💻

Estrutura Condicional - Parte 1

1 - Operadores Relacionais

1.1 - Conceito de Operadores Relacionais

Permite comparar dois valores do mesmo tipo básico para verificar relações como igualdade, diferença, maior ou menor. O resultado sempre será um valor lógico verdadeiro ou falso, conforme definido na tabela verdade."

👀

Acessibilidade visual:

Uma expressão utilizando operadores relacionais sempre resultará em uma valor verdade (valor verdade representa que a expressão pode ser falsa ou verdadeira).

Exemplo: se temos uma expressão (5 > 10), então o resultado desta expressão lógica utilizando o operador “> (maior)” será falso.

1.2 - Tabela com os operadores relacionais ou também conhecido como comparativos

OperaçãoOperador
Igual a=
Diferente de <>
Maior que >
Menor que<
Maior ou igual a>=
Menor ou igual a<=

1.3 - Exemplos de expressões comparativas

Suponha x igual a 10:

ExpressãoResultado
x > 0Verdadeiro
x = 9Falso
20 <= xFalso
x <> 10Falso
x >= 9Verdadeiro
10 >= xVerdadeiro

2 - Operadores Lógicos

2.1 - Conceito de Operadores Lógicos

Permite formações de valores lógicos (verdadeiro ou falso) conectados pelos operadores formando novas expressões lógicas.

2.2 - Tabela com os operadores lógicos e suas descrições

OperadorFunçãoDescrição
eConjunçãoVerdadeiro see todas condições forem verdadeiras
ouDisjunçãoVerdadeiro see pelo menos uma condição for verdadeira
nãoNegaçãoVerdadeiro see a condição for falsa

2. 3 - Assimilando o Operador “e”

Suponha x igual a 10

ExpressãoResultado
(x > 0) e (x = 10)
V V
Verdadeiro
(20 <= x) e (x <> 10)
F F
Falso
(x = 10) e (x < 2)
V F
Falso
(x >= 9) e (x = 10) e (x <> 20)
V V V
Verdadeiro
💡

Observação: Todas as condições devem ser verdadeiras para o resultado todo da expressão ser verdadeiro

👀

Acessibilidade visual:

Interpretando o Primeiro exemplo: Apresento duas expressões sendo: (x > 0) e (x = 10), para entender o operador “e” temos a seguinte regra: Todas as condições devem ser verdadeiras para o resultado ser verdadeiro. Isso significa que supondo que x vale 10 e a expressão diz que x é maior que 10, o primeiro resultado é verdadeiro, porém a conjunção utilizando o operador “e” diz que a outra expressão x é igual a 10, sendo assim a segunda expressão também é verdadeira. Logo se temos duas expressões verdadeiras, conforme citado na regra, toda expressão será verdadeira.

2.3.1 - Tabela Verdade do Operador “e” (Operação de Conjunção)

ABA e B
FFF
FVF
VFF
VVV

2.3.2 - Exemplos do Operador “e” (VisualG)

Imagine que João quer sair para jogar futebol com seus amigos, mas sua mãe estabeleceu duas condições:

  1. Ele precisa terminar a lição de casa.
  1. O tempo precisa estar ensolarado.

Se ambas as condições forem verdadeiras, João pode sair. Caso contrário, ele terá que ficar em casa.

Exemplo: recorte do algoritmo em VisualG

escreva(“João terminou a lição de casa ? (S/N):")
leia(licao_de_casa)
escreva(“O tempo está ensolarado ?.......(S/N):")
leia(tempo_ensolarado)
se (licao_de_casa = "S") e (tempo_ensolarado ="S") entao
   escreval("João pode sair de casa")
senão
   escreval("João não pode sair de casa")
fimse

2.4 - Assimilado o Operador “ou”

Suponha x igual a 10

ExpressãoResultado
(x < 0) ou (x =10)
F V
Verdadeiro
(20 <= x) ou (x <> 10)
F F
Falso
(x = 10) ou (x < 2)
V F
Verdadeiro
(x >= 9) ou (x <> 10) ou (x > 20)
V F F
Verdadeiro
💡

Observação: Pelo menos uma das condições devem ser verdadeiras para o resultado ser verdadeiro.

👀

Acessibilidade visual:

Interpretando o Primeiro exemplo: Apresento duas expressões sendo: (x < 0) e (x = 10), para entender o operador “ou” temos a seguinte regra: Pelo menos uma das condições deve ser verdadeira para o resultado seja verdadeiro. Isso significa que supondo que x vale 10 e a expressão diz que x é menor que 0, o primeiro resultado é falso, porém a disjunção utilizando o operador “ou” diz que a outra expressão x é igual a 10, sendo assim a segunda expressão é verdadeira. Logo se temos duas expressões uma verdadeira e outra falsa, conforme citado na regra, toda expressão será verdadeira.

2.4.1 - Tabela Verdade do Operador “ou” (operador de disjunção ou exclusiva)

ABA ou B
FFF
FVV
VFV
VVV

2.4.2 - Exemplos do Operador “ou”

Imagine que Mariana quer assistir TC, mas seus pais só permitem isso se ela terminar a lição de casa ou se for final de semana. Ou seja, basta que uma das duas condições seja verdadeira para que ela possa assistir TV.

Exemplo: recorte do trecho do algoritmo em VisualG.

   escreva(“Mariana Terminou a lição de casa ? (S/N):")
   leia(licao_de_casa)
   escreva(“É Final de Semana ?................(S/N):")
   leia(final_de_semana)
   se (licao_de_casa = "S") ou (final_de_semana ="S") entao
       escreval(“Mariana por assistir TV")
   senão
       escreval(“Mariana não pode assistir TV")
   fimse

2.5 - Assimilando o Operador “não”

Suponha x igual a 10

ExpressãoResultado
nao (x = 10)
V
Falso
nao (20 <= x)
F
Verdadeiro
nao ((x = 10) e (x < 2))
V F
F
V
Verdadeiro
💡

Observação: O operador “não” sempre irá inverter o resultado do expressão lógica, de F para V ou de V para F.

2.5.1 - Tabela Verdade do Operador “não” (Operação de negação)

ANão (A)
FV
VF

2.5.2 - Exemplos do Operador “nao” (VisualG)

Carlos quer jogar videogame, mas sua mãe disse que ele não pode jogar se houver tarefas pendentes. Ou seja, ele só pode jogar se NÃO houver tarefas para fazer.

Podemos representar essa situação com uma expressão lógica usando o operador "NÃO".

Exemplo do recorte do algoritmo em VisualG.

   escreva("Carlos tem tarefas pendentes (S/N):")
   leia(tarefas_pendentes)
   se nao(tarefas_pendentes = "S") entao
      escreval("João pode sair de casa")
   senão
      escreval("João não pode sair de casa")
   fimse

3 - Estruturas Condicionais – (Estruturas de Controle)

Conceito: Uma estrutura condicional permite que um bloco de comandos seja executado somente quando uma condição específica for satisfeita. Ela possibilita que o fluxo de execução do programa seja alterado com base em uma expressão lógica satisfeita.

3.1 - Estruturas Condicionais Simples

se <condicao> entao
	 <comando 1>
	 <comando 2>
	 <comando n>
fimse
💡

Observação:

  • Verdadeiro: executa o bloco de comandos;
  • Falso: pula o bloco de comandos.

3.1.1 - Exemplo de estrutura simples escrito para VisualG

Algoritmo "exemplo_condicional_simples“
// Descrição   : Exemplo de estrutura condicional simples
// Autor(a)    : Mauro Borges França
// Data atual  : 26/03/2025
var 
	 // Declaração de variável
	 idade: inteiro
inicio
   // Entrada de dados
   escreva("Digite a sua idade: ")
   leia(idade)
  
   // Estrutura condicional simples
   se idade >= 18 entao
	   	escreva("Você é maior de idade!")
   fimse
fimalgoritmo
💡

Observação: A estrutura do algoritmo deve estar devidamente indentada, pois a indentação organiza melhor os blocos de código.

3.2 - Estruturas Condicionais Composta

se <condicao> entao
	 <comando 1>
	 <comando 2>
	 <comando n>
senao
	 <comando 3>
	 <comando 4>
	 <comando n>
fimse
💡

Observação:

  • Verdadeiro: executa somente o bloco de comandos do “se”;
  • Falso: execute somente o bloco de comandos do “senao".

3.2.1 - Exemplo de estrutura composta escrito para VisualG

Algoritmo "exemplo_condicional_composta“
// Descrição   : Exemplo de estrutura condicional composta
// Autor(a)    : Mauro Borges França
// Data atual  : 26/03/2025
var 
	 // Declaração de variável
	 idade: inteiro
inicio
   // Entrada de dados
   escreva("Digite a sua idade: ")
   leia(idade)
  
   // Estrutura condicional composta
   se idade >= 18 entao
	  	escreva("Você é maior de idade!")
   senao
      escreva("Você é menor de idade!")
	 fimse
fimalgoritmo

3.2.2 - E se eu tiver mais de duas possibilidades ?

Contexto- Tradicionalmente, uma população é dividida em três faixas etárias: 
  • Jovens - Indivíduos de até 19 anos; 
  • Adultos - Indivíduos com idade entre 20 até 59 anos; 
  • Idosos - Indivíduos de 60 anos em diante.

3.2.3 - Estruturas condicionais compostas com mais de duas possibilidades

Se <condicao> entao
	 <comando 1>
	 <comando n>
Senao
	Se <condicao> então
	 	<comando 2>
		<comando n>
	Senao
		<comando 3>
		<comando n>
	fimse
fimse
💡

Observação:

  • Verdadeiro: executa somente o bloco de comandos do “se”;
  • Caso falso, então entra no “senao” e testa novamente a expressão lógica do próximo bloco “se”, caso seja verdadeiro executa o bloco deste condição;
  • Caso falso executa o bloco do próximo senao.

3.2.4 - Exemplo de estrutura composta com mais de duas possibilidades escrito para VisualG

Algoritmo "exemplo_condicional_composta2“
// Descrição   : Exemplo de estrutura condicional composta com mais de duas possibilidades
// Autor(a)    : Mauro Borges França
// Data atual  : 26/03/2025
var
	 // Declaração de variável
	 idade: inteiro
inicio
   // Entrada de dados
   escreva("Digite a sua idade: ")
   leia(idade)

   // Estrutura condicional composta com mais de duas possibilidades
   se idade <= 19 entao
		escreva("Você é uma pessoa jovem!")
   senao
		se (idade >= 20) e (idade <= 59) entao
     		escreva("Você é uma pessoa Adulta!")
      senao
 			escreva("Você é uma pessoa Idosa!")
      fimse
	fimse
fimalgoritmo

4 - Vamos para prática

💡

Dicas básicas para um melhor desempenho na elaboração dos algoritmos

  • Coloque o nome do Algoritmo;
  1. Preencha os dados iniciais: Autor, Descrição, Data, Etc.
  1. Declare as variáveis;
  1. Pense logicamente no desenvolvimento do problema e faça as operações;
  1. Utilize as estruturas de controle condicionais, calcule e mostre oque se pede;
  1. Faça a indentação corretamente;
  1. Faça o teste de mesa para garantir o funcionamento correto;
  1. Salve o algoritmo no Pendrive;
👩‍💻Lista 03 - Exercícios de Algoritmos - Estrutura Condicional - Parte 1

Copyleft 🄯 2025 - Professor Mauro Borges França.